plugins {
  id("com.android.application")
  id("org.jetbrains.kotlin.android")
  id("org.jetbrains.kotlin.plugin.compose")
  id("com.apollographql.apollo3")
}

android {
  namespace = "com.tlm.android"
  compileSdk = 34

  compileOptions {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
  }

  defaultConfig {
    applicationId = "com.tlm.android"
    minSdk = 26
    targetSdk = 34
    versionCode = 1
    versionName = "0.0.1"
    val gqlUrl = project.findProperty("TLM_GRAPHQL_URL") as String? ?: "http://10.0.2.2:4000/graphql"
    buildConfigField("String", "GRAPHQL_URL", "\"$gqlUrl\"")
  }

  buildTypes {
    release {
      isMinifyEnabled = false
    }
  }

  buildFeatures {
    compose = true
    buildConfig = true
  }

  kotlinOptions {
    jvmTarget = "17"
  }

  packaging {
    resources {
      excludes += "/META-INF/{AL2.0,LGPL2.1}"
    }
  }
}

apollo {
  service("tlm") {
    packageName.set("com.tlm.graphql")
    schemaFile.set(file("../../../packages/graphql-schema/schema.graphql"))
    srcDir("src/main/graphql")
  }
}

dependencies {
  val composeBom = platform("androidx.compose:compose-bom:2024.09.03")
  implementation(composeBom)
  implementation("androidx.compose.ui:ui")
  implementation("androidx.compose.material3:material3")
  implementation("androidx.compose.ui:ui-tooling-preview")
  debugImplementation("androidx.compose.ui:ui-tooling")
  implementation("androidx.activity:activity-compose:1.9.3")
  implementation("androidx.lifecycle:lifecycle-runtime-ktx:2.8.7")
  implementation("androidx.work:work-runtime-ktx:2.9.1")

  implementation("com.apollographql.apollo3:apollo-runtime:3.8.5")
  implementation("com.squareup.okhttp3:okhttp:4.12.0")
  implementation("com.google.android.material:material:1.12.0")
}